J.P.Lee Bsc(hons) HomePage : : Home

J. P. Lee BSc(Hons)
Programmer
Databases, graphics, audio, networks.
C, C++,C# Delphi, PHP, HTML, WML, Javascript, CG, HLSL, Unity3D

UK website
Established July 1999

Click here to contact me

Home

Programming

Internet

General

Intro

My CV

Game programming

Intro

My CV

Game programming

Audio

VRML

PHP

Food

Intro

Digital Effects program for Atari ST using Replay 16 sampling module module
Written entirely in 68000 assembler code.

;  Realtime FX routines for ATARI ST
;  using Replay 16 cartridge
;  sets up interrupt routine
;  so that effect is ran as background task
;BUT dont move the mouse during processing

Timer_Default	equ	43

SOUND_FX
        MOVEM.L A0-A5/D0-D7,-(SP)       save registers
	DC.W	$A00A		;HIDE MOUSE
;get current screen resolution
	move.w	#4,-(sp)
	trap	#14
	addq.l	#2,sp
	move.w	d0,Res
;get current palette
	bsr	STORE_PALETTE

;change to LOW resolution
	move.w	#0,-(sp)
	move.L	#-1,-(sp)
	move.L	#-1,-(sp)
	move.w	#5,-(sp)
	trap	#14
 	add.l	#12,sp
;LOAD UP FRONT PANEL AND OTHER GRAPHICS	
	bsr	LOAD_PICTURE	;load front panel and set palette
	TST.L	D0
	BMI	Exit_Program
;Find Screen Address
	move.w	#2,-(sp)
	trap	#14
	addq.l	#2,sp
	move.l	d0,ScreenBase	store screen start address
	MOVE.L	#NeoPic,A0
	ADD.L	#128,A0
	MOVE.L	A0,FrontPanel
	BSR	SET_PARAMETERS	SET PARAMETERS TO CURRENT PRESET!
	bsr	Set_Knob_Values	set knobs to appropriate positions
	BSR	SHOW_PANEL	;DISPLAY THE PANEL (320*105)
	bsr	UPDATE_KNOBS	SHOW KNOBS IN CURRENT SETTINGS
	BSR	SELECT_LCD	;SHOW SELECTION

MOVE.W	#58,D1	X
	MOVE.W	#84,D2	Y
	MOVE.L	#TEXT1,A0
	BSR	PLOT_STRING	show preset name
	MOVE.W	#0,Current
	BSR	START_INT
MORE	
	bsr	Show_Levels
	BSR	Check_Keyboard
	CMPI.B	#32,D0		;SPACE BAR TO EXIT (JUST 4 NOW ANYWAY!)
        BNE	MORE
	BSR	STOP_INT
;change to ORIGINAL SCREENresolution
	move.w	Res,-(sp)
	move.L	#-1,-(sp)
	move.L	#-1,-(sp)
	move.w	#5,-(sp)
	trap	#14
	add.l	#12,sp
;load original palette
	bsr	RESTORE_PALETTE
Exit_Program
	DC.W	$A009		;SHOW MOUSE
	MOVEM.L (SP)+,A0-A5/D0-D7       load registers
	MOVE.W	#20,-(SP)		exit cleanly
	MOVE.W	#$4C,-(SP)
	TRAP	#1
	RTS

START_INT
	MOVEM.L A0-A3/D0-D2,-(SP)       save registers
;DISABLE_CRACKLE
	MOVE.W	#5,-(SP)	;INTERRUPT NUMBER TO STOP(0-14)
	MOVE.W	#26,-(SP)
	TRAP	#14
	ADDQ.L	#4,SP
;set up timer and start the interrupt
        MOVE.W  #8,-(SP)
        MOVE.W  #27,-(SP)       call Jenabint
        TRAP    #14		START INTERRUPT
        ADDQ.L  #4,SP           enable timer b interrupt
        BSR     super           call supervisor mode
        MOVE.B  #0,$FFFA1B      stop timer b
        LEA     spa(PC),A0      address of interrupt routine variables
        LEA     ECHO(PC),A3   load address of interrupt routine
        MOVE.L  A3,-(SP)                
	MOVE.W	#Timer_Default,-(SP)	;	SAMPLE RATE DATA
	MOVE.W	#$01,-(SP)	;	CONTROL
        MOVE.W  #1,-(SP)	1=timer b
        MOVE.W  #31,-(SP)
        TRAP    #14
        ADD.L   #12,SP                  start timer b
        BSR     usuper                  exit supervisor mode
        MOVEM.L (SP)+,A0-A3/D0-D2       load registers
        RTS                                     and exit...
	even
spa     DS.L    2                       interrupt routine variables
	RTS

STOP_INT
	bsr	super
;stop timer
        MOVE.B  #0,$FFFA1B      stop timer b
	bsr	usuper
        MOVE.W  #8,-(SP)
        MOVE.W  #26,-(SP)       call Jdisint
        TRAP    #14		STOP INTERRUPT
        ADDQ.L  #4,SP           
;ENABLE_CRACKLE
	MOVE.W	#5,-(SP)	;INT NUMBER TO ENABLE
	MOVE.W	#27,-(SP)
	TRAP	#14
	ADDQ.L	#4,SP
	RTS

super   CLR.L   -(SP)
        MOVE.W  #$20,-(SP)
        TRAP    #1
        ADD.L   #$6,SP                  call supervisor
        LEA     stksve(PC),A0
        MOVE.L  D0,(A0)                 save stack
        RTS                             and exit...

usuper  LEA     stksve(PC),A0
        MOVE.L  (A0),D0
        MOVE.L  D0,-(SP)                load stack
        MOVE    #$20,-(SP)
        TRAP    #1
        ADDQ.L  #6,SP                   back to user mode
        RTS     
	even
stksve  DS.L    1               stack save

;TIMER B INTERRUPT
ECHO
        MOVEM.L A0-A1/D0-D3,-(SP)       save registers
	MOVE.L	#PARAMETERS,A1	;GET BASE OF INFO BLOCK
	MOVE.W	0(A1),D2	;D2= CURRENT position within buffer
	move.W	4(A1),d3	;D3= Feed_Back LEVEL 1 -64
;buffer is at 20(a1) onwards
	move.w	$fb0000,D0	;READ A/D INTO D0
	AND.W	#$FFFE,D0	;halve the volume OF INPUT SIGNAL
	ASR.W	#1,D0		;
	move.w	d0,level
	MOVE.W	20(A1,D2.W),D1	;D1=Delayed VALUE FROM BUFFER

mulS.W	d1,d3
	ASR.L	#5,D3		D4=PROPORTIONAL FEEDBACK

ANDI.L	#$FFFF,D3	
	ADD.W	D0,D3		;add curent i/p signal
	MOVE.W	D3,20(A1,D2.W)	;PUT CURRENT SAMPLE+F_BACK IN BUFFER 
	AND.W	#$FFFE,D1	;half the volume of delay o/p
	ASR.W	#1,D1
;D0 IS DRY SIGNAL
;D1 IS EFFECT OUTPUT
;SCALE D0 USING 10(A0)  (MIX_DRY)
;	MULS.W	10(a0),D0
;	ASR.L	#5,D0		
;	ANDI.L	#$FFFF,D0	D0 IS NOW ATTENUATED

;SCALE D1 USING 12(A0)  (MIX_FX)
;	MULS.W	12(a0),D1
;	ASR.L	#5,D1		
;	ANDI.L	#$FFFF,D1	D1 IS NOW ATTENUATED

ADD.W	D0,D1		;( OUTPUT mix )
	move.l	#$fa8000,A0	;OUTPUT D1 TO D/A
	move.b	0(a0,d1.w),D0	; 
	ADDQ.W	#2,D2		;MOVE POINTER TO NEXT WORD
	CMP.W	2(A1),D2	;reached end?
	BLE	NOTEND		;branch if  d2 < d3
	MOVE.W	#0,D2		;reset curent pos
NOTEND	MOVE.W	D2,0(a1)	;store current pos
;mod_Depth is at 6(A1)	( WORD )
;mod_Rate is at 8(A1)	  ''
;mod_Cnt is at 14(A1)	( word )
	cmp.W	#0,6(a1)	IS MOD_DEPTH = 0	
	beq	INT_END		YES SO NO MODULATION
	move.w	14(a1),d0	get Mod_Cnt
	addq.w	#1,d0		increment Mod_Cnt
	cmp.w	8(a1),d0	reached mod_rate yet?
	BLT	No_Mod_Yet	
;counter has reached target so alter modulation value
	clr.l	d0		reset count
	move.w	16(a1),d1	get current mod_val
	CMPI.W	#$FF,18(a1)		which direction?
	beq	ModNeg		negative 
;mod dir is up
	addq.w	#1,d1		increment mod val	
	cmp.W	6(a1),d1	;has it reached Mod Depth?
	blt	Do_Mod		no so just set new mod value	
	move.w	#$FF,18(a1)	;yes so change direction
	bra	Do_Mod
ModNeg
	subq.w	#1,d1		dec mod_val
	cmpi.b	#0,d1
	bne	Do_Mod
	move.w	#0,18(a1)	CHANGE DIRECTION
Do_Mod
	move.w	d1,16(a1)	store new ModVal
	addi.b	#Timer_Default,d1
	move.b	d1,$FFFA21	STORE NEW VALUE IN TIMER
No_Mod_Yet
	move.w	d0,14(a1)	store new Mod_Cnt
INT_END
	MOVEM.L (SP)+,A0-A1/D0-D3       load registers  
	BCLR    #0,$FFFA0F              acknowledge interrupt
	RTE                                     and exit

Show_Levels
	movem.l	a0/d0,-(sp)
	MOVE.L	#NEOPIC+4,A0	GET ADDRESS OF PALETTE
	move.w	#$410,30(A0)	SET COLOUR 15 TO DARK
	move.w	#$310,28(A0)	14
	move.w	#$230,26(A0)	13
	move.w	#$130,24(A0)	12
	move.w	#$030,22(A0)	11
	move.w	#$020,20(A0)	10
	move.w	#$010,18(A0)	9
	MOVE.W	Peak,D0
	cmpi.w	#16380,D0
	blT	lev6
	move.w	#$721,30(A0)
lev6	cmpi.w	#8192,D0
	blT	lev5
	move.w	#$611,28(A0)
lev5	cmpi.w	#4096,D0
	blT	lev4
	move.w	#$560,26(A0)
lev4	cmpi.w	#2048,D0
	blT	lev3
	move.w	#$350,24(A0)
lev3	cmpi.w	#1024,D0
	blT	lev2
	move.w	#$050,22(A0)
lev2	cmpi.w	#128,D0
	blT	lev1
	move.w	#$030,20(A0)
lev1	cmpi.w	#64,D0
	blt	nolev
	move.w	#$020,18(A0)
nolev
;DO THE FADE DOWN SLOWER TO MAKE CHANGES MORE APPARENT
	SUBI.W	#256,D0
	CMP.W	LEVEL,D0
	Bge	LEVIS0
	MOVE.W	LEVEL,D0	
LEVIS0
	MOVE.W	D0,PEAK
;SET THE NEW PALLETEE
	move.l	#NeoPic+4,-(sp)
	move.w	#6,-(sp)
	trap	#14
	addq.l	#6,sp
	movem.l	(sp)+,a0/d0
	
	rts

Check_Keyboard
; key available?
	MOVE.W	#2,-(SP)
	MOVE.W	#1,-(SP)
	TRAP	#13
	ADDQ.L	#4,SP
	TST	D0
	BEQ	NO_PRESS		;no? then end
;GET AVAILABLE KEY
	MOVE.W	#2,-(SP)
	MOVE.W	#2,-(SP)
	TRAP	#13
	ADDQ.L	#4,SP
noop
	CMP.B	#0,D0	;IF 0 THEN MUST BE A FUNCTION KEY
	BNE	Not_Function
	bsr	Function_Keys	
Not_Function
NO_PRESS
	RTS

Function_Keys
	MOVEM.L	A0-A2/D0-D3,-(SP)
	MOVE.W	Current_Knob,d1		find # of currently selected knob
	asl.w	#1,d1		MULTIPLY BY TWO (GET WORD OFFSET)
	MOVE.L	#Knob_Value,A0	GET START OF KNOB VALUE LIST
	add.l	d1,a0
	MOVE.L	#Knob_Param_Inc,a1	get value to add
	add.l	d1,a1
	MOVE.L	#Knob_Param,a2	get current parameter value
	add.l	d1,a2
	move.w	(a1),d2		get param inc value
;a0 now points to selected knob value  (0 to 16)	
	swap	d0	check scan codes instead of ascii

CMPI.B	#68,D0		wasit F10
	BNE	TRY_F1_9
	BSR	STORE_PRESET
TRY_F1_9
	CMPI.B	#59,D0	FUNCTION KEY 1
	BLT	AN
	CMP.B	#66,D0	FUNCTION KEY 8
	BGT	AN
	MOVE.W	D0,CURRENT_PRESET
	SUBI.W	#59,CURRENT_PRESET
	BSR	USE_PRESET
	bra	FKEY
AN
	cmpi.b	#82,d0		was it 'insert' ie enter number
	bne	CCU
	BSR	Enter_Parameter
	bra	FKEY
CCU	cmpi.b	#72,d0	was it cursur uo
	BNE	CCD
	ADD.W	#1,(a0)		increment the knob position
	ADD.W	d2,(a2)	 increment param
	bsr	SET_PARAMETERS
	BSR	UPDATE_CURRENT_KNOB	REDRAW KNOB	AND LCD
	bra	FKEY
CCD	cmpi.b	#80,d0	cursur down?
	bne	CCL
	SUB.w	#1,(a0)		CURRENT KNOB VALUE
	SUB.W	d2,(a2)	increment param
	bsr	SET_PARAMETERS		;SETS AND LIMITS TO MAX ALLOWED
	BSR	UPDATE_CURRENT_KNOB	 REDRAW KNOB AND LCD
	bra	FKEY
CCL	cmpi.b	#75,d0	cursur LEFT?
	BNE	CCR
;deselect current knob
	BSR	DESELECT_LCD
	SUB.W	#1,Current_Knob
;select new current knob
CCR	cmpi.b	#77,d0	cursur RIGHT?
	BNE	FKEY
;deselect current knob
	BSR	DESELECT_LCD
	ADD.W	#1,Current_Knob
;select new current knob
FKEY	
;keep variables within bounds
	move.w	Current_Knob,d0
	cmpi.w	#0,d0		less than zero?
	bge	CheckOF
	move.w	#0,d0
CheckOF
	cmpi.w	#5,d0
	ble	CK_OK
	move.w	#5,d0
CK_OK
	move.w	d0,Current_Knob
;SHOW CURRENT SELECTION
	BSR	SELECT_LCD

MOVEM.L	(SP)+,A0-A2/D0-D3
	RTS
SELECT_LCD
	MOVEM.L	A0/D0-D6,-(SP)
	MOVE.W	#0,D0		SRC X
	MOVE.W	#154,D1		SRC Y
	MOVE.W	CURRENT_KNOB,D2
	ASL.W	#1,D2
	MOVE.L	#KNOB_COORDS,A0
	ADD.L	D2,A0
	MOVE.W	(A0),D2
	SUBQ.W	#5,D2		DEST X COORD
	MOVE.W	#56,D3		DEST Y COOORF
	MOVE.W	#26,D4		WIDTH
	MOVE.W	#2,D5		HEIGHT
	BSR	BLIT		COPY ONTO SCREEN
	MOVE.W	#70,D3		DEST Y COOORF
	BSR	BLIT		COPY ONTO SCREEN
	MOVEM.L	(SP)+,A0/D0-D6
	RTS
DESELECT_LCD
	MOVEM.L	A0/D0-D6,-(SP)
	MOVE.W	#0,D0		SRC X
	MOVE.W	#156,D1		SRC Y
	MOVE.W	CURRENT_KNOB,D2
	ASL.W	#1,D2
	MOVE.L	#KNOB_COORDS,A0
	ADD.L	D2,A0
	MOVE.W	(A0),D2
	SUBQ.W	#5,D2		DEST X COORD
	MOVE.W	#56,D3		DEST Y COOORF
	MOVE.W	#26,D4		WIDTH
	MOVE.W	#2,D5		HEIGHT
	BSR	BLIT		COPY ONTO SCREEN
	MOVE.W	#70,D3		DEST Y COOORF
	BSR	BLIT		COPY ONTO SCREEN
	MOVEM.L	(SP)+,A0/D0-D6
	RTS

Enter_Parameter
	MOVEM.L	A0-A5/D0-D7,-(SP)
	move.w	Current_Knob,d1		find which oparam to edit
	ASL.W	#1,D1		*2 FOR WORD OFFSET
	MOVE.L	#Knob_Param,a5
	add.l	d1,a5		a2 points to data to be changed
	move.l	#Knob_LCD,A0
	add.l	d1,a0
	MOVE.W	(A0),D1	GET X POSITION OF LCD SCREEN
	move.w	d1,d7	remember x coord
	move.w	#59,d2		y coord
	move.l	#tbuff,a0
	move.l	#"    ",(a0)
	bsr	plot_string	clear window
	move.l	#kbuff,a4
	MOVE.L	#0,(A4)		CLEAR 4 BYTES OF BUFFER
	move.w	#0,4(a4)	
	CLR.L	D3		NO KEYS ENTERED YET
NEXT_INPUT
	bsr	Show_Levels
	MOVE.W	#2,-(SP)
	MOVE.W	#1,-(SP)
	TRAP	#13
	ADDQ.L	#4,SP
	TST	D0
	BEQ	NEXT_INPUT		;no? then wait
;GET KEY INTO D0
	MOVE.W	#2,-(SP)
	MOVE.W	#2,-(SP)
	TRAP	#13
	ADDQ.L	#4,SP
	ANDI.L	#$FF,D0		MASK TO BYTE SIZE
	CMPI.B	#27,D0		ESCAPE ??
	BEQ	IN_ESC
	CMPI.B	#13,D0		RETURN ??
	BEQ	IN_FIN
;only accept key if it is a number
	cmpi.b	#"0",d0
	blt	NEXT_INPUT
	cmpi.b	#"9",d0
	bgt	NEXT_INPUT
	cmpi.b	 #3,d3		max no keys entered?
	beq	NEXT_INPUT
	ADDQ.L	#1,D3		INCREMENT KEY COUNTER
	MOVE.B	D0,(A4)+	STORE KEY IN BUFFER
;SHOW INPUT CHARS SO FAR
	move.w	d7,d1		x coord
	move.w	#59,d2		y coord
	move.l	#tbuff,a0
	move.l	#"    ",(a0)
	bsr	plot_string	clear window
	move.l	#kbuff,a0
	move.w	d7,d1		x coord
	bsr	plot_string	print digits entered so far
	BRA	NEXT_INPUT	GET ANOTHER ONE
IN_FIN
;	MOVE.B	#0,(A4)		TERMINATE STRING
;convert string to parameter value 
	move.l	#KBUFF,A0
	BSR	DECBIN		CONVERT TO BINARY NUMBER
	MOVE.W	D0,(a5)		STORE IN PARAMETER FOR THE KNOB	
	bsr	set_Parameters	error check value and put in int data
	BSR	Set_Knob_Values		POINT KNOB CORRECTLY OOOEERR!!
IN_ESC	bsr	UPDATE_CURRENT_KNOB	REDRAW KNOB+TEXT
	MOVEM.L	(SP)+,A0-A5/D0-D7
	RTS

UPDATE_KNOBS
	move.w	#5,d0
	MOVE.W	Current_Knob,D1
Next_Knob
	MOVE.W	D0,Current_Knob
	BSR	UPDATE_CURRENT_KNOB
	DBRA	D0,Next_Knob
	MOVE.W	D1,Current_Knob
	RTS

UPDATE_CURRENT_KNOB
	movem.l	a0-a2/d0-d5,-(sp)
;plots knob in new position
;also puts text in the lcd underneath it
;table holds new position
	MOVE.W	Current_Knob,D0		GET # OF SELECTED KNOB
	CMP.W	#6,D0	IS KNOB VALUE VALID?
	BLT	KNOB_VALID
	MOVE.W	#5,D0
	MOVE.W	D0,Current_Knob
KNOB_VALID
	ANDI.l	#$0F,D0
	asl.W	#1,d0
	move.l	#Knob_coords,a0
	move.l	#Knob_value,a1
	add.l	d0,a0
	add.l	d0,a1
	move.w	(a0),d2		set dest x(from stored list
	move.w	#32,d3		set dest y
	move.w	(a1),d0		get frame number ( Knob_Value )
;must be 0 to 16
	CMPI.W	#0,D0
	BGE	KnobVAlPos
	move.w	#0,(a1)
KnobValPos
	cmpi.w	#16,d0
	BLE	ValOk
	move.w	#16,(a1)
ValOk	move.w	(a1),d0		get frame number ( Knob_Value )
	asl.w	#4,d0		*16 to give src x
	move.w	#120,d1		src y
	move.w	#16,d4		width
	move.w	#16,d5		height
	bsr	blit
;now print the value in the lcd
	MOVE.W	Current_Knob,D0		GET # OF SELECTED KNOB
	asl.w	#1,d0
	move.l	#Tbuff,A0	buffer for temporary text storage
	MOVE.L	#Knob_LCD,A1	LCD X COORDS
	add.l	d0,a1
	MOVE.L	#Knob_Param,A2	PARAMETER VALUES
	add.l	d0,a2
	move.l	#"    ",(a0)	string of spaces	
	move.w	#0,4(a0)	terminated
	MOVE.W	(A1),D1		;GET LCD X COORD
	MOVE.W	#59,D2		;LCD Y COORD
	BSR	PLOT_STRING	;print the spaces(clear LCD)
	MOVE.W	(A2),d0		;get PARAMETER VALUE
	bsr	BINDEC		;CONVERT TO TEXT
Skipit	cmpi.b	#" ",(a0)+	;miss out leading spaces
	beq	Skipit
	subq.l	#1,a0
	BSR	PLOT_STRING	;print new value
	movem.l	(sp)+,a0-a2/d0-d5
	RTS

Set_Knob_Values
;reads parameters and decides which is apropriate frame to show
	movem.l	a0-a2/d0-d2,-(sp)
	move.l	#Knob_Param,a0
	move.l	#Knob_Max,a1
	move.l	#Knob_Value,a2
	move.w	#5,d2	(number of knobs
Next_Knob_Value
	move.w	(a0)+,d0	parameter value	
	move.w	(a1)+,d1	Maximum Value Allowed
	cmp.w	#0,d0	dont do a divide by zero!!!
	beq	v_is_0
;scale to give # from 0 to 16
	MULS.W	#16,D0
	divu.w	d1,D0		d0=d0/d1	
	ANDI.W	#$FF,D0
v_is_0	move.w	d0,(a2)+	store new knob position
	dbra	d2,Next_Knob_Value
	movem.l	(sp)+,a0-a2/d0-d2
	rts

SET_PARAMETERS
	movem.l	a0-a1/d0-d2,-(sp)
;COPIES KNOB PARAMETER VALUES TO PARAMETER BLOCK
;IF VALUE EXCEEDS Knob_Max then old value is copied back
	MOVE.L	#Knob_Param,A0	current value
;FIRST CHECK ALL FOR LESS THAN ZERO!
	MOVE.W	#5,D0
CNZ	CMPI.W	#0,(A0)
	BGT	PNZ
	MOVE.W	#0,(A0)
PNZ	ADDQ.L	#2,A0		NEXT WORD
	DBRA	D0,CNZ

MOVE.L	#Knob_Param,A0	current value
	MOVE.L	#Knob_Max,a1	Max value allowed

MOVE.W	0(A0),d0	get delay (Ms)
	CMP.W	0(A1),D0	DOES VALUE EXCEED MAX?
	BLT	Del_OK		
	move.w	0(a1),d0	if so then set to max value	
	move.w	d0,0(a0)	put back
Del_OK
	CMPI.W	#0,D0
	BNE	DelOK2
	move.w	#1,d0
DelOK2	move.w	d0,LengthMs
	mulu.w	#27,d0
	CMP.W	LENGTH,D0
	bLT	dont_clear
	bsr	Clear_Buffer
dont_clear
	move.w	d0,Length

MOVE.W	4(A0),d0
	CMP.W	4(A1),D0	DOES VALUE EXCEED MAX?
	BLT	MR_OK
	MOVE.W	4(A1),d0
MR_OK	MOVE.W	d0,4(A0)
	andi.l	#$1ff,d0
	asl.w	#4,d0	;gives real range of 0 to 1023
	addi.w	#30,d0

MOVE.W	d0,Mod_Rate

;set Modulation depth
	MOVE.W	2(A0),D0
	CMP.W	2(A1),D0
	BLT	MD_OK
	MOVE.W	2(A1),D0	SET TO MAX VAL
	MOVE.W	d0,2(A0)	STORE IN PARAM LIST
MD_OK	
	cmp.w	Mod_Depth,d0
;	beq	Mod_Same
;	cmpi.w	#0,d0	is it zero?
;	BNE	MOD_SAME
;mod has changed to zero so reset timer
;	bsr	super
;	move.b	#Timer_Default,$FFFA21	STORE NEW VALUE IN TIMER
;	bsr	usuper
Mod_Same
	cmpi.w	#0,d0	is it zero?
	beq	DepOK
	addq.w	#6,d0	only add 6 if not zero!
DepOK	MOVE.W	d0,Mod_Depth	STORE IN INTERRUPT PARAMETER BLOCK

MOVE.W	6(A0),d0
	CMP.W	6(A1),D0	DOES VALUE EXCEED MAX?
	BLT	FB_OK	
	MOVE.W	6(A1),d0
	MOVE.W	d0,6(A0)
FB_OK	MOVE.W	d0,Feed_Back

MOVE.W	8(A0),d0
	CMP.W	8(A1),D0	DOES VALUE EXCEED MAX?
	BLT	MixD_OK	
	MOVE.W	8(A1),d0
	MOVE.W	d0,8(A0)
MixD_OK	MOVE.W	d0,Mix_Dry

MOVE.W	10(A0),d0
	CMP.W	10(A1),D0	DOES VALUE EXCEED MAX?
	BLT	MixF_OK	
	MOVE.W	10(A1),d0	get max value
	MOVE.W	d0,10(A0)	store as param value
MixF_OK	MOVE.W	d0,Mix_FX
	movem.l	(sp)+,a0-a1/d0-d2
	RTS

BINDEC
;CONVERT # IN D0 TO ASCII STRING AT A0
	MOVEM.L	A0/D0-D1,-(SP)
;CLEAR BUFFER FOR 4 DIGITS
	MOVE.L	#"   0",(A0)
	ADD.L	#4,A0
	move.b	#0,(a0)
	MOVE.W	#3,D1
BD1	DIVU.w	#10,D0		remainder in upper word
	SWAP	D0		   ''     '  lower
	CMP.L	#0,D0		IS NUMBER ALL DONE>?
	BEQ	BDEND
	ADDI.B	#"0",D0		
	MOVE.B	D0,-(A0)
	CLR.W	D0		clear lower word
	SWAP	D0		quotient in lower word
	DBRA	D1,BD1
BDEND	MOVEM.L	(SP)+,A0/D0-D1
	RTS
DECBIN
;CONVERT STRING AT A0 TO # IN D0
	MOVEM.L	A0/D1,-(SP)
	CLR.L	D0
NEXCHA	MOVE.B	(A0)+,D1
	CMPI.B	#0,D1
	BEQ	DB_DONE
	MULU.W	#10,D0
	SUBI.W	#"0",D1
	ADD.W	D1,D0
	CMPI.B	#0,(A0)
	BNE	NEXCHA
DB_DONE	MOVEM.L	(SP)+,A0/D1
	RTS
Clear_Buffer
;CALLED WHENEVER DELAY TIME IS ALTERED
	movem.l	d0/A0,-(sp)
	move.l	#buffer,a0
	move.w	#2700/4,d0
nex	move.l	#0,(a0)+
	dbra	d0,nex
	movem.l	(sp)+,d0/A0
	rts

SHOW_PANEL
;COPY PANEL GRAPHICS TO SCREEN
	MOVE.L	FrontPanel,a0
	MOVE.L	ScreenBase,a1
	Move.w	#104*40,d0
DoMore	move.l	(a0)+,(a1)+
	dbra	d0,DoMore
	rts
LOAD_PICTURE
	MOVE.W	#0,-(SP)
	MOVE.L	#PicName,-(sp)
	move.w	#$3d,-(sp)	open file for reading
	trap	#1
	addq.l	#8,sp
	tst.l	d0
	bmi	FileError	!some sort of error??
	MOVE.L	#NeoPic,-(sp)
	MOVE.L	#32000,-(SP)	# OF BYTES TO LOAD
	MOVE.W	d0,-(SP)		FILE HANDLE
	MOVE.W	#$3F,-(SP)	READ FILE
	TRAP	#1
	add.l	#12,sp
	TST.L	D0
	BMI	FileError
;set colour palette
	move.l	#NeoPic+4,-(sp)
	move.w	#6,-(sp)
	trap	#14
	addq.l	#6,sp
FileError
	RTS

STORE_PALETTE
	BSR	super
	move.l	#palette,a0
	move.l	#$ffff8240,a1	start of palette chip
	move.w	#16,d0	#words to copy
NexCol	move.w	(a1)+,(a0)+
	dbra	d0,NexCol
	bsr	usuper
	RTS
RESTORE_PALETTE
	move.l	#Palette,-(sp)
	move.w	#6,-(sp)
	trap	#14
 	addq.l	#6,sp
	RTS

STORE_PRESET
;STORE CURRENT SETTINGS IN CVURRENT PRESET
	movem.l	a0-a1/d0,-(sp)
	MOVE.L	#Knob_Param,a0
	MOVE.L	#PRESETS,A1
	MOVE.W	Current_Preset,d0
	asl.w	#5,d0	MULTIPLY BY 32
	add.l	d0,a0
	move.l	0(a0),0(a1)
 	move.L	4(a0),4(a1)
	move.L	8(a0),8(a1)
	movem.l	(sp)+,a0-a1/d0
	RTS
USE_PRESET
;COPIES DATA FROM PRESET LIST INTO CURRENT SETTINGS
;SHOWS CURRENT PRESET NAME AND NUMBER
	movem.l	a0-a1/d0-d2,-(sp)
	MOVE.L	#Knob_Param,a1
	MOVE.L	#PRESETS,A0
	MOVE.W	Current_Preset,d0
	asl.w	#5,d0
	add.l	d0,a0
	move.l	0(a0),0(a1)
	move.L	4(a0),4(a1)
	MOVE.L	8(A0),8(A1)
	add.l	#12,a0		a0 points to start of preset name
	MOVE.W	#58,D1	X
	MOVE.W	#84,D2	Y
	bsr	PLOT_STRING	show preset name
	BSR	SET_PARAMETERS	SET PARAMETERS TO CURRENT PRESET!
	bsr	Set_Knob_Values	set knobs to appropriate positions
	bsr	UPDATE_KNOBS	SHOW KNOBS IN CURRENT SETTINGS
	movem.l	(sp)+,a0-a1/d0-d2
	RTS

PLOT_STRING
;USES PLOT_CHAR
;A0 = ADDRESS OF START OF TEXT TO PLOT
;D1=X
;D2=Y
	MOVEM.L	A0/D0-D7,-(SP)
M_TEXT	MOVE.B	(A0)+,D0
	CMPI.B	#0,D0
	BEQ	TEXT_DONE
	BSR	PLOT_CHAR
	add.w	d4,d1
	BRA	M_TEXT
TEXT_DONE
	MOVEM.L	(SP)+,A0/D0-D7
	RTS

PLOT_CHAR
	movem.l	d0-d3,-(sp)
;PLOTS THE CHARACTER IN D0 AT D1,D2  (D1=X COOrd D2=YCOORD)
;returning width of char in d4
;CONVERT ASCII CODE TO CHARACTER NUMBER(AS ON DEFINED GRAPHICS)
	andi.l	#$ff,d0		mask off any other crap
	move.w	d2,d3		dest y
	move.w	d1,d2		dest x
	move.w	#106,d1		source y
	move.w	#8,d4		width
	move.w	#10,d5		height
;check for small space first
	CMPI.B	#" ",D0
	BNE	IS_B_SPACE
	MOVE.W	#8*12,D0	POINT x TO SMALL SPACE DEF
	BRA	get_char_def
IS_B_SPACE
	CMPI.B	#"_",D0		. =  SPACE ON LARGE SCREEN
	BNE	IS_A_LETTER
	MOVE.W	#11*27,D0	POINT source x TO BIG SPACE DEF
	move.w	#140,d1		source y
	move.w	#11,d4		width
	move.w	#10,d5		height
	BRA	get_char_def
IS_A_LETTER
	cmpi.b	#"A",d0
	blt	IS_B_CURSOR
	SUBI.B	#"A",D0
	MULU.W	#11,d0		source x = # *11
	move.w	#140,d1		source y
	move.w	#11,d4		width
	BRA	get_char_def
IS_B_CURSOR
	CMPI.B	#"@",D0		_ =  CURSOR ON big LCD
	BNE	IS_A_NUMBER
	MOVE.W	#11*26,D0	POINT TO BIG CURSOR DEF
	move.w	#140,d1		source y
	move.w	#11,d4		width
	BRA	get_char_def
IS_A_NUMBER
	CMPI.B	#":",D0
	BGT	Char_Not_Fnd
	SUBI.B	#"0",D0		CONVERT TO NUMBER
	asl.l	#3,d0		source x = # *8
get_char_def
	bsr	blit
Char_Not_Fnd
	movem.l	(sp)+,d0-d3
	rts
*************************************************************************
* BLIT - Perform a blit from screen to screen. Uses, but preserves	*
* the following registers...						*
* D0 - Left FROM	s x						*
* D1 - Top FROM		s y						*
* D2 - Left TO		d x						*
* D3 - Top TO		d y						*
* D4 - WIDTH								*
* D5 - HEIGHT								*
* D7 - Logical Operation want replace  						*
*************************************************************************
blit:	MOVEM.L	D0-D7/A0-A6,-(SP)	;Preserve Registers
	move.b	#3,d7	dest is replaced with source
	LEA	bitblt(PC),A6		;Address of blit table
	MOVE.L	FrontPanel,18(A6)	;Store 'From' address
	MOVE.L	ScreenBase,32(A6)	;Store 'To' Address
	MOVE.W	D0,14(A6)		;Store Left from position
	MOVE.W	D1,16(A6)		;Store Top from position
	MOVE.W	D2,28(A6)		;Store Left To position
	MOVE.W	D3,30(A6)		;Store Top To position
	MOVE.W	D4,0(A6)		;Store width. 
	MOVE.W	D5,2(A6)		;Store height.
low_rez:
	MOVE.W	#2,4(A6)		;Set up Blit variables

MOVE.W	#8,22(A6)		;for Low resolution
	MOVE.W	#8,36(A6)		;low res
any_rez:
	MOVE.L	#0,42(A6)		;Set up Blit variables 
	MOVE.B	D7,10(A6)		;for any resolution
	MOVE.W	#0,6(A6)
	MOVE.W	#0,8(A6)
	DC.W	$A007			;Do the Blit!
blit_exit:
	MOVEM.L	(SP)+,D0-D7/A0-A6	;Restore registers
	RTS				;and return.
******************************
* Data for the Blit Routine *
*****************************
	EVEN
bitblt:	DC.W	0	;Width				+0
	DC.W	0	;Height				+2
	DC.W	2	;No. Planes			+4
	DC.W	0	;fg_col				+6
	DC.W	0	;bg_col				+8
	DC.B	0,0,0,0	;log. ops			+10
	DC.W	0	;left source x			+14
	DC.W	0	;top source y			+16
	DC.L	0	;Source screen top address	+18
	DC.W	8	;word in line (8=low 4=med)	+22
	DC.W	160	;160 for med/low		+24
	DC.W	2					+26
	DC.W	0	;left dest x			+28
	DC.W	0	;top dest y			+30
	DC.L	0	;dest screen top address	+32
	DC.W	8	;word in line			+36
	DC.W	160	;line in plane			+38
	DC.W	2					+40
	DC.L	0	;Pattern Address		+42
	DC.W	0					+46
	DC.W	0					+48
	DC.W	0					+50
	DS.B	30					+52
	even
*************************
* End of BLIT Data      *
*************************
	EVEN
Palette	ds.w	18

;Bloody hell !!! that broken key IS Essential Within a file name!!!!

;PicName		dc.b	"A:\AUTO\PANEL.NEO",0,0
PicName		dc.b	"A:\PANEL.NEO",0,0
	even
PreFileName	dc.b	"A:\DIGI_FX.PRS",0,0
	even
HANDLE	DS.W	1
;\\\\\\\\\\\\\
;general purpose buffer for storing result of bindec
;and input of decbin
Tbuff	ds.b	16
kbuff	ds.b	16

TEXT1	DC.B	"DIGI_FX___BY_J_LEE_",0
	EVEN

Res		DS.W	1
ScreenBase	ds.l	1
FrontPanel	ds.l	1	holds address of start of graphics

level	DS.W	1
Peak	dc.w	32768
Current_Preset	DC.W	0
Current_Knob	dc.w	0	this holds # of selected knob
;list of x positions for the knobs
Knob_Coords	dc.w	62,108,148,198,250,290
;x coords of LCD 
Knob_LCD	DC.W	54,108,142,198,250,282
;list of what frame each knob is currently (0-16)
Knob_Value	dc.w	8,8,8,8,8,8
;list of actual parameter values associated with the knobs
Knob_Param	dc.w	200,0,64,16,16,16
;list of maximum values of these parameters
Knob_Max	dc.w	1000,32,256,32,32,32
Knob_Param_Inc	dc.w	62,2,16,2,2,2

;THIS AREA HOLDS PARAMETERS OF EFFECT
LengthMs	dc.w	200		;200 ms delay

PARAMETERS
Current		DS.W	1	(+0)
Length		Dc.W	5400	DELAY BUFFER LENGTH	  (+2)
Feed_Back	Dc.W	16	range of 0 to 64	  (+4)
Mod_depth	dc.W	0	(+6)
Mod_Rate	DC.W	200	(+8)	(range of 0 to20
Mix_Dry		DC.w	16	(+10)
Mix_Fx		DC.w	16	(+12)
Mod_Cnt		DS.W	1	(+14)
Mod_Val		ds.w	1	(+16)	# to add to timer value( $2e)
Mod_Direction	ds.w	1	(+18)	00 = inc  -1=dec
Buffer		DS.B	27004	(+20)
	even
;this is where graphics is loaded
NeoPic		ds.b	32002

;THIS BLOCK HOLDS DATA FOR PRESETS (32 BYTES /PRESET )
PRESETS
;FIRST THE PARAMETER SETTINGS 
; ( DELAY,MOD DEPTH,MOD RATE,FEEDBACK,DRY MIX,FX MIX )
; ' =SPACE

;PRESET 1
	dc.w	40,0,64,16,16,16
	DC.B	"_ROOM______________",0
;PRESET 2
	dc.w	200,0,64,16,16,16
	DC.B	"_HALL______________",0
;PRESET 3
	dc.w	800,0,64,16,16,16
	DC.B	"_GRAND_CANYON______",0
;PRESET 4
	dc.w	6,0,64,28,16,16
	DC.B	"_SEWAGE_PIPE_______",0
;PRESET 5
	dc.w	8,30,128,24,16,16
	DC.B	"_FAR_OUT_FLANGER___",0
;PRESET 6
	dc.w	10,10,20,26,16,16
	DC.B	"_FROGGY_PHASER_____",0
;PRESET 7
	dc.w	60,0,64,16,16,16
	DC.B	"_BATHROOM__________",0
;PRESET 8
	dc.w	30,0,64,16,16,16
	DC.B	"_TEAPOT____________",0

; ***** end of file *****?